Автор перевода: Майкл "Antares" Клишин	Предыдущая | Следующая | Оглавление

Microphone.silenceLevel

Доступность

Flash Player 6.

Синтаксис

active_mic.silenceLevel:Number

Описание

Свойство, доступное только для чтения; число, определяющее порог при захвате звука, пересечение которого вызывает Microphone.onActivity(true). Значение по умолчанию —  10.

Пример

В примере ниже уровень тишины изменяется пользователем при помощи компонента NumericStepper с именем silenceLevel_nstep. Компонент ProgressBar с именем silenceLevel_pb изменяет свое поведение в зависимости от того, превышен ли уровень тишины. Если нет, отображается уровень активности аудиопотока.

var silenceLevel_pb:mx.controls.ProgressBar;
var silenceLevel_nstep:mx.controls.NumericStepper;

this.createEmptyMovieClip("sound_mc", this.getNextHighestDepth());
var active_mic:Microphone = Microphone.get();
sound_mc.attachAudio(active_mic);

silenceLevel_pb.label = "Уровень активности: %3";
silenceLevel_pb.mode = "manual";
silenceLevel_nstep.minimum = 0;
silenceLevel_nstep.maximum = 100;
silenceLevel_nstep.value = active_mic.silenceLevel;

var nstepListener:Object = new Object();
nstepListener.change = function (evt:Object) {
  active_mic.setSilenceLevel(evt.target.value, active_mic.silenceTimeOut);
};
silenceLevel_nstep.addEventListener("change", nstepListener);

this.onEnterFrame = function() {
  silenceLevel_pb.setProgress(active_mic.activityLevel, 100);
};
active_mic.onActivity = function (active:Boolean) {
  if (active) {
    silenceLevel_pb.indeterminate = false;
    silenceLevel_pb.setStyle("themeColor", "haloGreen");
    silenceLevel_pb.label = "Уровень активности: %3";
  } else {
    silenceLevel_pb.indeterminate = true;
    silenceLevel_pb.setStyle("themeColor", "0xFF0000");
    silenceLevel_pb.label = "Уровень активности: (неактивен)";
  }
};

См. также

Microphone.gain, Microphone.setSilenceLevel()

Посмотреть комментарии LiveDocs		Предыдущая | Следующая | Оглавление